1 # Process this file with autoconf to produce a configure script.
2 
3 AC_PREREQ([2.69])
4 AC_INIT([got-portable],
5 	m4_esyscmd_s(util/got-portable-ver.sh),
6 	[thomas@xteddy.org])
7 AC_CONFIG_AUX_DIR(etc)
8 AC_CONFIG_SRCDIR([lib/rcsutil.h])
9 AM_INIT_AUTOMAKE([foreign subdir-objects])
10 
11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
12 AC_SUBST(VERSION)
13 AC_SUBST(GOT_RELEASE)
14 
15 AC_CANONICAL_HOST
16 
17 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
18 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
19 # empty default.
20 : ${CFLAGS=""}
21 
22 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
23 # AC_CHECK_HEADER doesn't give us any other way to update the include
24 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
25 SAVED_CFLAGS="$CFLAGS"
26 SAVED_CPPFLAGS="$CPPFLAGS"
27 SAVED_LDFLAGS="$LDFLAGS"
28 
29 # Checks for programs.
30 AC_PROG_CC
31 AC_PROG_CPP
32 AC_PROG_INSTALL
33 AC_PROG_LN_S
34 AC_PROG_MAKE_SET
35 AC_PROG_YACC
36 AC_PROG_RANLIB
37 PKG_PROG_PKG_CONFIG
38 AC_USE_SYSTEM_EXTENSIONS
39 
40 # Checks for header files.
41 AC_CHECK_HEADERS([ \
42 	fcntl.h \
43 	langinfo.h \
44 	limits.h \
45 	linux/landlock.h \
46 	locale.h \
47 	netdb.h \
48 	netinet/in.h \
49 	paths.h \
50 	poll.h \
51 	stddef.h \
52 	stdint.h \
53 	stdlib.h \
54 	string.h \
55 	sys/ioctl.h \
56 	sys/param.h \
57 	sys/poll.h \
58 	sys/queue.h \
59 	sys/socket.h \
60 	sys/time.h \
61 	sys/tree.h \
62 	util.h \
63 	unistd.h \
64 	wchar.h \
65 ])
66 
67 # Checks for typ edefs, structures, and compiler characteristics.
68 AC_CHECK_HEADER_STDBOOL
69 AC_C_INLINE
70 AC_TYPE_INT64_T
71 AC_TYPE_MODE_T
72 AC_TYPE_OFF_T
73 AC_TYPE_PID_T
74 AC_TYPE_SIZE_T
75 AC_TYPE_SSIZE_T
76 AC_TYPE_UINT16_T
77 AC_TYPE_UINT32_T
78 AC_TYPE_UINT64_T
79 AC_TYPE_UINT8_T
80 
81 # Check for ifgroupreq which is only available on BSD.
82 AC_CHECK_TYPES([struct ifgroupreq])
83 
84 # Check for sockaddr_storage.  On some systems, ss_len is filled out, although
85 # this is not mandated by POSIX, and hence systems such as linux, don't have
86 # it.
87 AC_CHECK_TYPES([struct sockaddr_storage], [], [], [
88 #include <sys/types.h>
89 #include <sys/socket.h>
90 ])
91 
92 # Same thing as sockaddr_storage above, only now check if the member exists in
93 # the struct as well.
94 AC_CHECK_MEMBERS([struct sockaddr_storage.ss_len], , ,
95 	[ #include <netdb.h>
96 	  #include <netinet/in.h>
97 	  #include <sys/socket.h> ]
98 )
99 
100 AC_CHECK_MEMBERS([struct sockaddr.sa_len], , ,
101 	[ #include <netdb.h>
102 	  #include <netinet/in.h>
103 	  #include <sys/socket.h> ]
104 )
105 
106 # Both checks above will result in:
107 #
108 # HAVE_STRUCT_SOCKADDR_AS_LEN
109 # SS_LEN
110 #
111 # Either being defined or not.
112 
113 # Look for library needed for flock.
114 AC_SEARCH_LIBS(flock, bsd)
115 
116 # Checks for library functions.
117 AC_FUNC_FORK
118 AC_FUNC_FSEEKO
119 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
120 AC_FUNC_MALLOC
121 AC_FUNC_MMAP
122 AC_FUNC_REALLOC
123 AC_FUNC_STRERROR_R
124 AC_FUNC_STRNLEN
125 AC_CHECK_FUNCS([ \
126 	dup2 \
127 	flock \
128 	getcwd \
129 	localtime_r \
130 	memchr \
131 	memmove \
132 	memset \
133 	mkdir \
134 	munmap \
135 	nl_langinfo \
136 	realpath \
137 	regcomp \
138 	rmdir \
139 	setlocale \
140 	socket \
141 	setresgid \
142 	setresuid \
143 	setproctitle \
144 	strcasecmp \
145 	strchr \
146 	strcspn \
147 	strdup \
148 	strerror \
149 	strlcpy \
150 	strncasecmp \
151 	strndup \
152 	strrchr \
153 	strspn \
154 	strstr \
155 	strtol \
156 	strtoul \
157 	wcwidth \
158 ])
159 
160 AM_CONDITIONAL([HAVE_SETPROCTITLE], [test "x$ac_cv_func_setproctitle" = xyes])
161 AM_CONDITIONAL([HAVE_SETRESGID], [test "x$ac_cv_func_setresgid" = xyes])
162 AM_CONDITIONAL([HAVE_SETRESUID], [test "x$ac_cv_func_setresuid" = xyes])
163 
164 # Siphash support.
165 AC_CHECK_FUNCS([SipHash])
166 AM_CONDITIONAL([HAVE_SIPHASH], [test "x$ac_cv_func_SipHash" = xyes])
167 
168 # Check for functions with a compatibility implementation.
169 AC_REPLACE_FUNCS([ \
170 	asprintf \
171 	closefrom \
172 	explicit_bzero \
173 	fmt_scaled \
174 	freezero \
175 	getdtablecount \
176 	getline \
177 	getprogname \
178 	recallocarray \
179 	reallocarray \
180 	strlcat \
181 	strlcpy \
182 	strndup \
183 	strsep \
184 	strtonum \
185 ])
186 
187 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
188 # musl does not set optarg to NULL for flags without arguments (although it is
189 # not required to, but it is helpful) 3) there are probably other weird
190 # implementations.
191 AC_LIBOBJ(getopt)
192 
193 # Check the platform we're compiling on.
194 AC_MSG_CHECKING(platform)
195 case "$host_os" in
196 	*linux*)
197 		AC_MSG_RESULT(linux)
198 		PLATFORM=linux
199 		;;
200 	*freebsd*)
201 		AC_MSG_RESULT(freebsd)
202 		PLATFORM=freebsd
203 		;;
204 	*darwin*)
205 		AC_MSG_RESULT(darwin)
206 		PLATFORM=darwin
207 		;;
208 	*netbsd*)
209 		AC_MSG_RESULT(netbsd)
210 		PLATFORM=netbsd
211 		;;
212 	*dragonfly*)
213 		AC_MSG_RESULT(dragonfly)
214 		PLATFORM=dragonflybsd
215 		;;
216 	*)
217 		AC_MSG_RESULT(unknown)
218 		PLATFORM=unknown
219 		;;
220 esac
221 AC_SUBST(PLATFORM)
222 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
223 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
224 AM_CONDITIONAL([HOST_DARWIN], [test "$PLATFORM" = "darwin"])
225 AM_CONDITIONAL([HOST_NETBSD], [test "$PLATFORM" = "netbsd"])
226 AM_CONDITIONAL([HOST_DRAGONFLYBSD], [test "$PLATFORM" = "dragonflybsd"])
227 
228 if test x"$PLATFORM" = "xdarwin"; then
229 	# Check for and/or set HOMEBREW_PREFIX.  brew is a common way of
230 	# installing applications.  The other is MacPorts.
231 	#
232 	# Before Apple Silicon existed (M1 onward), the paths for applications
233 	# installed via homebrew was typically /usr/local.  However, with M1
234 	# onward, this changed to a different path.
235 	#
236 	# Rather than hardcode this, check for HOMEBREW_PREFIX in the
237 	# environment if it's already set, and use it.  Otherwise, check for
238 	# brew(1) and use that.  If that fails, default to /usr/local
239 	#
240 	# This also means that MacPorts should continue to work.
241 	#
242 	# But with MacPorts, we should also check --prefix, and use that if it
243 	# has been supplied.
244 	#
245 	# In both cases, the variable HOMEBREW_PREFIX is used for both.
246 	HB_PREFIX=""
247 	FOUND_BISON="no"
248 	GNUBISON=""
249 	if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"; then
250 		# HOMEBREW_PREFIX not set, check for brew(1)
251 		if command -v brew >/dev/null 2>&1; then
252 			AC_MSG_NOTICE("HOMEBREW_PREFIX set via 'brew --prefix'")
253 			export HOMEBREW_PREFIX="$(brew --prefix)"
254 		fi
255 
256 		if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"
257 		then
258 			# Default.
259 			if test -z "${prefix}" -o "${prefix}" = "NONE"; then
260 				export HOMEBREW_PREFIX="/usr/local"
261 				HB_PREFIX="/usr/local"
262 				AC_MSG_NOTICE("HOMEBREW_PREFIX defaulting to $HB_PREFIX")
263 			else
264 				HB_PREFIX="$(eval echo ${prefix})"
265 				if test "$HB_PREFIX" = "NONE"; then
266 					HB_PREFIX="/opt/local"
267 				else
268 					AC_MSG_NOTICE("HOMEBREW_PREFIX using --prefix")
269 				fi
270 				export HOMEBREW_PREFIX="$HB_PREFIX"
271 			fi
272 		fi
273 	fi
274 
275 	AC_MSG_NOTICE("HOMEBREW_PREFIX determined as: $HOMEBREW_PREFIX")
276 
277 	if ! test -x "${HOMEBREW_PREFIX}/opt/bison/bin/bison"; then
278 		AC_MSG_WARN([
279 			     "***********************************************************
280 			     GNU Bison not found: ${HOMEBREW_PREFIX}/opt/bison/bin/bison
281 			     ***********************************************************
282 
283 			     Falling back to checking either /usr/local or \${prefix}"
284 		])
285 
286 		FOUND_BISON="no"
287 		AC_MSG_WARN("Trying ${HB_PREFIX}/opt/bison/bin/bison")
288 		if test -x "${HB_PREFIX}/opt/bison/bin/bison"; then
289 			export HOMEBREW_PREFIX="/usr/local"
290 			FOUND_BISON="yes"
291 			GNUBISON="${HB_PREFIX}/opt/bison/bin/bison"
292 		fi
293 
294 		if test "$FOUND_BISON" = "no"; then
295 			HB_PREFIX="/opt/local"
296 			AC_MSG_WARN("Trying ${HB_PREFIX}/bin/bison")
297 
298 			if test -x "${HB_PREFIX}/bin/bison"; then
299 				export HOMEBREW_PREFIX="${HB_PREFIX}"
300 				GNUBISON="${HB_PREFIX}/bin/bison"
301 				FOUND_BISON="yes"
302 			fi
303 		fi
304 	else
305 		FOUND_BISON="yes"
306 		GNUBISON="${HOMEBREW_PREFIX}/opt/bison/bin/bison"
307 	fi
308 
309 	if test "$FOUND_BISON" = "no"; then
310 		AC_MSG_ERROR("*** Couldn't find GNU BISON ***")
311 	fi
312 
313 	AC_MSG_NOTICE("Found GNU Bison as: $GNUBISON")
314 
315 	# Override YACC here to point to the GNU version of bison.
316 	export YACC="${GNUBISON} -y"
317 	export LDFLAGS="-L${HOMEBREW_PREFIX}/opt/ncurses/lib -L${HOMEBREW_PREFIX}/opt/openssl@3/lib $LDFLAGS"
318 	export CPPFLAGS="-I${HOMEBREW_PREFIX}/opt/ncurses/include -I${HOMEBREW_PREFIX}/opt/openssl@3/include $CPPFLAGS"
319 	export PKG_CONFIG_PATH="${HOMEBREW_PREFIX}/opt/ncurses/lib/pkgconfig"
320 	export PKG_CONFIG_PATH="$PKG_CONFIG_PATH:${HOMEBREW_PREFIX}/opt/openssl@3/lib/pkgconfig"
321 fi
322 
323 # Landlock detection.
324 AC_MSG_CHECKING([for landlock])
325 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
326     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
327 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
328 	AC_MSG_RESULT(yes)
329 else
330 	AC_MSG_RESULT(no)
331 fi
332 
333 # Clang sanitizers wrap reallocarray even if it isn't available on the target
334 # system. When compiled it always returns NULL and crashes the program. To
335 # detect this we need a more complicated test.
336 AC_MSG_CHECKING([for working reallocarray])
337 AC_RUN_IFELSE([AC_LANG_PROGRAM(
338 		[#include <stdlib.h>],
339 		[return (reallocarray(NULL, 1, 1) == NULL);]
340 	)],
341 	AC_MSG_RESULT(yes),
342 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])],
343 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
344 )
345 AC_MSG_CHECKING([for working recallocarray])
346 AC_RUN_IFELSE([AC_LANG_PROGRAM(
347 		[#include <stdlib.h>],
348 		[return (recallocarray(NULL, 1, 1, 1) == NULL);]
349 	)],
350 	AC_MSG_RESULT(yes),
351 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])],
352 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
353 )
354 
355 # Look for imsg_init in libutil.
356 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
357 if test "x$found_imsg_init" = xyes; then
358 	AC_DEFINE(HAVE_IMSG)
359 else
360 	AC_LIBOBJ(imsg)
361 	AC_LIBOBJ(imsg-buffer)
362 fi
363 
364 # libevent (for gotwebd).  Lifted from tmux.
365 # Look for libevent. Try libevent_core or libevent with pkg-config first then
366 # look for the library.
367 PKG_CHECK_MODULES(
368 	LIBEVENT_CORE,
369 	[libevent_core >= 2],
370 	[
371 		AM_CPPFLAGS="$LIBEVENT_CORE_CFLAGS $AM_CPPFLAGS"
372 		CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
373 		LIBS="$LIBEVENT_CORE_LIBS $LIBS"
374 		found_libevent=yes
375 	],
376 	found_libevent=no
377 )
378 if test x$found_libevent = xno; then
379 	PKG_CHECK_MODULES(
380 		LIBEVENT,
381 		[libevent >= 2],
382 		[
383 			AM_CPPFLAGS="$LIBEVENT_CFLAGS $AM_CPPFLAGS"
384 			CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
385 			LIBS="$LIBEVENT_LIBS $LIBS"
386 			found_libevent=yes
387 		],
388 		found_libevent=no
389 	)
390 fi
391 if test x$found_libevent = xno; then
392 	AC_SEARCH_LIBS(
393 		event_init,
394 		[event_core event event-1.4],
395 		found_libevent=yes,
396 		found_libevent=no
397 	)
398 fi
399 AC_CHECK_HEADER(
400 	event2/event.h,
401 	AC_DEFINE(HAVE_EVENT2_EVENT_H),
402 	[
403 		AC_CHECK_HEADER(
404 			event.h,
405 			AC_DEFINE(HAVE_EVENT_H),
406 			found_libevent=no
407 		)
408 	]
409 )
410 if test "x$found_libevent" = xno; then
411 	AC_MSG_ERROR("libevent not found")
412 fi
413 
414 # libcrypto (via libssl for SHA information)
415 PKG_CHECK_MODULES(
416 	LIBCRYPTO,
417 	libcrypto,
418 	[
419 	 	AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
420 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
421 		LIBS="$LIBCRYPTO_LIBS $LIBS"
422 		found_libcrypto=yes
423 	],
424 	[
425 	 	found_libcrypto=no
426 	]
427 )
428 
429 if test "x$found_libcrypto" = "xyes"; then
430 	AC_DEFINE(HAVE_LIBCRYPTO)
431 fi
432 
433 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
434 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
435 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
436 
437 # Don't define HAVE_BSD_UUID on darwin (Apple) as this breaks the BSD API.
438 # Instead, use the UUID implementation wrapper that's in compat/ plus uuid
439 # ossp
440 if test "x$found_uuid" = "xyes" -a "x$PLATFORM" != "darwin"; then
441 	AC_DEFINE(HAVE_BSD_UUID)
442 else
443 	PKG_CHECK_MODULES(
444 		LIBUUID,
445 		uuid,
446 		[
447 			AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
448 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
449 			LIBS="$LIBUUID_LIBS $LIBS"
450 			found_libuuid=yes
451 		],
452 		[
453 			found_libuuid=no
454 		]
455 	)
456 
457 	if test "x$found_libuuid" = "xno"; then
458 		AC_CHECK_HEADER(
459 			uuid.h,
460 			found_libuuid=yes,
461 			found_libuuid=no)
462 	fi
463 fi
464 
465 if test "x$found_libuuid" = "xno"; then
466 	AC_MSG_ERROR("*** couldn't find uuid ***")
467 fi
468 
469 PKG_CHECK_MODULES(
470 	ZLIB,
471 	zlib,
472 	[
473 	 	AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
474 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
475 		LIBS="$ZLIB_LIBS $LIBS"
476 		found_zlib=yes
477 	],
478 	[
479 	 	found_zlib=no
480 	]
481 )
482 
483 if test "x$found_zlib" = "xno"; then
484 	AC_CHECK_HEADER(
485 		zlib.h,
486 		,
487 		found_zlib=no)
488 fi
489 
490 if test "x$found_zlib" = "xno"; then
491 	AC_MSG_ERROR("*** couldn't find zlib ***")
492 fi
493 
494 if test "$PLATFORM" = "linux"; then
495 	PKG_CHECK_MODULES(
496 		LIBMD,
497 		libmd,
498 		[
499 			AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
500 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
501 			LIBS="$LIBMD_LIBS $LIBS"
502 		],
503 		[
504 			AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
505 		]
506 	)
507 	PKG_CHECK_MODULES(
508 		LIBBSD,
509 		libbsd-overlay,
510 		[
511 			AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
512 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
513 			LIBS="$LIBBSD_LIBS $LIBS"
514 			found_libbsd=yes
515 			AC_DEFINE(HAVE_LIBBSD)
516 		],
517 		[
518 			AC_MSG_ERROR("*** couldn't find libbsd-overlay via pkg-config")
519 		]
520 
521 	)
522 fi
523 
524 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
525 # some declarations.
526 AC_CHECK_DECL(
527 	TAILQ_CONCAT,
528 	found_queue_h=yes,
529 	found_queue_h=no,
530 	[#include <sys/queue.h>]
531 )
532 AC_CHECK_DECL(
533 	TAILQ_PREV,
534 	,
535 	found_queue_h=no,
536 	[#include <sys/queue.h>]
537 )
538 AC_CHECK_DECL(
539 	TAILQ_FOREACH_SAFE,
540 	,
541 	found_queue_h=no,
542 	[#include <sys/queue.h>]
543 )
544 
545 if test "x$found_queue_h" = xyes; then
546 	AC_DEFINE(HAVE_QUEUE_H)
547 else
548 	AC_MSG_ERROR("*** sys/queue.h missing key defines ***)
549 fi
550 
551 
552 # Look for __progname.
553 AC_MSG_CHECKING(for __progname)
554 AC_LINK_IFELSE([AC_LANG_SOURCE(
555 	[
556 		#include <stdio.h>
557 		#include <stdlib.h>
558 		extern char *__progname;
559 		int main(void) {
560 			const char *cp = __progname;
561 			printf("%s\n", cp);
562 			exit(0);
563 		}
564 	])],
565 	[AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
566 	AC_MSG_RESULT(no)
567 )
568 
569 PKG_CHECK_MODULES(
570 	LIBPANELW,
571 	panelw,
572 	found_panel=yes,
573 	found_panel=no
574 )
575 
576 PKG_CHECK_MODULES(
577 	LIBPANELW,
578 	gnupanelw,
579 	found_panel=yes,
580 	found_panel=no
581 )
582 
583 PKG_CHECK_MODULES(
584 	LIBPANELW,
585 	panel,
586 	found_panel=yes,
587 	found_panel=no
588 )
589 if test "x$found_panel" = "xno"; then
590 	AC_CHECK_LIB(panelw, update_panels,,
591 		AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"])
592 	)
593 
594 	LIBPANELW_LIBS="-lpanelw"
595 fi
596 
597 PKG_CHECK_MODULES(
598 	LIBNCURSES,
599 	ncursesw,
600 	found_ncurses=yes,
601 	found_ncurses=no
602 )
603 if test "x$found_ncurses" = xyes; then
604 	AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
605 	CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
606 	LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
607 else
608 	AC_CHECK_LIB(
609 		ncursesw,
610 		setupterm,
611 		found_ncurses=yes,
612 		found_ncurses=no
613 	)
614 	if test "x$found_ncurses" = xyes; then
615 		AC_CHECK_HEADER(
616 			ncurses.h,
617 			AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
618 			CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
619 			LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
620 			found_ncurses=no
621 		)
622 	fi
623 fi
624 if test "x$found_ncurses" = xyes; then
625 	AC_DEFINE(HAVE_NCURSES_H)
626 else
627 	# No ncurses, try curses.
628 	AC_CHECK_LIB(
629 		cursesw,
630 		setupterm,
631 		found_curses=yes,
632 		found_curses=no
633 	)
634 	AC_CHECK_HEADER(
635 		curses.h,
636 		,
637 		found_curses=no)
638 	if test "x$found_curses" = xyes; then
639 		AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
640 		CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
641 		LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
642 		AC_DEFINE(HAVE_CURSES_H)
643 	else
644 		AC_MSG_ERROR("curses not found")
645 	fi
646 fi
647 
648 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
649 # variables.
650 AC_SUBST(AM_CPPFLAGS)
651 CPPFLAGS="$SAVED_CPPFLAGS"
652 AC_SUBST(AM_CFLAGS)
653 CFLAGS="$SAVED_CFLAGS"
654 AC_SUBST(AM_LDFLAGS)
655 LDFLAGS="$SAVED_LDFLAGS"
656 
657 AC_CONFIG_FILES([Makefile
658 		 compat/Makefile
659 		 libexec/Makefile
660 		 libexec/got-read-tree/Makefile
661 		 libexec/got-fetch-pack/Makefile
662 		 libexec/got-index-pack/Makefile
663 		 libexec/got-read-blob/Makefile
664 		 libexec/got-read-commit/Makefile
665 		 libexec/got-read-gitconfig/Makefile
666 		 libexec/got-read-gotconfig/Makefile
667 		 libexec/got-read-object/Makefile
668 		 libexec/got-read-pack/Makefile
669 		 libexec/got-read-patch/Makefile
670 		 libexec/got-read-tag/Makefile
671 		 libexec/got-send-pack/Makefile
672 		 got/Makefile
673 		 gotadmin/Makefile
674 		 gotwebd/Makefile
675 		 tog/Makefile
676 		 Makefile.common:Makefile.common.in])
677 AC_OUTPUT
678 
679 executables="$(eval echo ${exec_prefix}/bin)"
680 helpers="$(eval echo ${libexecdir})"
681 manpages="$(eval echo ${mandir})"
682 
683 echo "
684 Configured got-portable with:
685 
686  Version:      $VERSION
687 
688  Prefix:       ${prefix}
689  Executables:  ${executables}
690  Helpers:      ${helpers}
691  Man pages:    ${manpages}
692 "